想詢問一個reg 網卡相關的問題

jeff8023

想做一個REG檔在不同的電腦上設定網卡數值
路徑如下 HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\Tcpip\Parameters\Interfaces\{網卡名稱}
想更改 RegisterAdapterName  RegistrationEnabled 這兩個參數
但每台電腦Interfaces底下  的  {網卡名稱}  都不一樣 該怎處理才可以通用

wusun

根據：請問電腦的網路IP設定參數存在哪裡？

以下：SetTcpIp_Param.bat

@echo off
setlocal EnableDelayedExpansion

set RegisterAdapterName=0
set RegistrationEnabled=1

set Network_Key=HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Network\{4D36E972-E325-11CE-BFC1-08002BE10318}
set Interfaces_Key=HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\Tcpip\Parameters\Interfaces

for /f "tokens=4 delims={}" %%i in ('reg.exe query "%Network_Key%"') do (
  set GUID={%%i}
  reg.exe query "%Interfaces_Key%\!GUID!" >nul 2>&1 && (
    for /f "tokens=3" %%j in ('reg.exe query "%Network_Key%\!GUID!\Connection" /v "Name"') do (echo %%j:)
    reg add "%Interfaces_Key%\!GUID!" /v "RegisterAdapterName" /t REG_DWORD /d "%RegisterAdapterName%" /f >nul && echo Set RegisterAdapterName to %RegisterAdapterName%
    reg add "%Interfaces_Key%\!GUID!" /v "RegistrationEnabled" /t REG_DWORD /d "%RegistrationEnabled%" /f >nul && echo Set RegistrationEnabled to %RegistrationEnabled%
  )
)

pause

jeff8023

wusun 發表於 2017-10-26 13:21
根據：請問電腦的網路IP設定參數存在哪裡？

以下：SetTcpIp_Param.bat

請問一下我要有修改什麼嗎？ 因為我用上去不能用....

wusun

jeff8023 發表於 2017-10-28 00:16
請問一下我要有修改什麼嗎？ 因為我用上去不能用....

你唯一要修改的，只有把其後數值改成你想要的設定值

set RegisterAdapterName=0
set RegistrationEnabled=1

你有把其存成bat檔，再執行嗎？
出現什麼錯誤訊息，有截圖嗎？